Menu

- Learn
- Documentation
  - Language Reference
  - Library Reference
  - Feature Overview
  - DMD Manual
  - Articles
- Packages
- Community
  - Bug Tracker
  - Forums
  - IRC
  - D on GitHub
  - Wiki
  - Review Queue
  - Twitter
  - More Links
- Resources
  - NEW Library Reference Preview
  - D-Specific Tools
  - Visual D
  - Editors
  - IDEs
  - Tutorials
  - Books
  - The D Style
  - Glossary
  - Acknowledgments
  - Sitemap

Search
Report a bug
If you spot a problem with this page, click here to create a Bugzilla issue.
Improve this page
Quickly fork, edit online, and submit a pull request for this page. Requires a signed-in GitHub account. This works well for small changes. If you'd like to make larger changes you may want to consider using a local clone.

# core.sync.rwmutex

The read/write mutex module provides a primitive for maintaining shared read access and mutually exclusive write access.
License:
Boost License 1.0
Authors:
Sean Kelly

Source: core/sync/rwmutex.d

class ReadWriteMutex;
  This class represents a mutex that allows any number of readers to enter, but when a writer enters, all other readers and writers are blocked.
  Please note that this mutex is not recursive and is intended to guard access to data only. Also, no deadlock checking is in place because doing so would require dynamic memory allocation, which would reduce performance by an unacceptable amount. As a result, any attempt to recursively acquire this mutex may well deadlock the caller, particularly if a write lock is acquired while holding a read lock, or vice-versa. In practice, this should not be an issue however, because it is uncommon to call deeply into unknown code while holding a lock that simply protects data.
  Examples:

      import core.atomic, core.thread, core.sync.semaphore;

      static void runTest(ReadWriteMutex.Policy policy)
      {
          scope mutex = new ReadWriteMutex(policy);
          scope rdSemA = new Semaphore, rdSemB = new Semaphore,
                wrSemA = new Semaphore, wrSemB = new Semaphore;
          shared size_t numReaders, numWriters;

          void readerFn()
          {
              synchronized (mutex.reader)
              {
                  atomicOp!"+="(numReaders, 1);
                  rdSemA.notify();
                  rdSemB.wait();
                  atomicOp!"-="(numReaders, 1);
              }
          }

          void writerFn()
          {
              synchronized (mutex.writer)
              {
                  atomicOp!"+="(numWriters, 1);
                  wrSemA.notify();
                  wrSemB.wait();
                  atomicOp!"-="(numWriters, 1);
              }
          }

          void waitQueued(size_t queuedReaders, size_t queuedWriters)
          {
              for (;;)
              {
                  synchronized (mutex.m_commonMutex)
                  {
                      if (mutex.m_numQueuedReaders == queuedReaders &&
                          mutex.m_numQueuedWriters == queuedWriters)
                          break;
                  }
                  Thread.yield();
              }
          }

          scope group = new ThreadGroup;

          // 2 simultaneous readers
          group.create(&readerFn); group.create(&readerFn);
          rdSemA.wait(); rdSemA.wait();
          assert(numReaders == 2);
          rdSemB.notify(); rdSemB.notify();
          group.joinAll();
          assert(numReaders == 0);
          foreach (t; group) group.remove(t);

          // 1 writer at a time
          group.create(&writerFn); group.create(&writerFn);
          wrSemA.wait();
          assert(!wrSemA.tryWait());
          assert(numWriters == 1);
          wrSemB.notify();
          wrSemA.wait();
          assert(numWriters == 1);
          wrSemB.notify();
          group.joinAll();
          assert(numWriters == 0);
          foreach (t; group) group.remove(t);

          // reader and writer are mutually exclusive
          group.create(&readerFn);
          rdSemA.wait();
          group.create(&writerFn);
          waitQueued(0, 1);
          assert(!wrSemA.tryWait());
          assert(numReaders == 1 && numWriters == 0);
          rdSemB.notify();
          wrSemA.wait();
          assert(numReaders == 0 && numWriters == 1);
          wrSemB.notify();
          group.joinAll();
          assert(numReaders == 0 && numWriters == 0);
          foreach (t; group) group.remove(t);

          // writer and reader are mutually exclusive
          group.create(&writerFn);
          wrSemA.wait();
          group.create(&readerFn);
          waitQueued(1, 0);
          assert(!rdSemA.tryWait());
          assert(numReaders == 0 && numWriters == 1);
          wrSemB.notify();
          rdSemA.wait();
          assert(numReaders == 1 && numWriters == 0);
          rdSemB.notify();
          group.joinAll();
          assert(numReaders == 0 && numWriters == 0);
          foreach (t; group) group.remove(t);

          // policy determines whether queued reader or writers progress first
          group.create(&writerFn);
          wrSemA.wait();
          group.create(&readerFn);
          group.create(&writerFn);
          waitQueued(1, 1);
          assert(numReaders == 0 && numWriters == 1);
          wrSemB.notify();

          if (policy == ReadWriteMutex.Policy.PREFER_READERS)
          {
              rdSemA.wait();
              assert(numReaders == 1 && numWriters == 0);
              rdSemB.notify();
              wrSemA.wait();
              assert(numReaders == 0 && numWriters == 1);
              wrSemB.notify();
          }
          else if (policy == ReadWriteMutex.Policy.PREFER_WRITERS)
          {
              wrSemA.wait();
              assert(numReaders == 0 && numWriters == 1);
              wrSemB.notify();
              rdSemA.wait();
              assert(numReaders == 1 && numWriters == 0);
              rdSemB.notify();
          }
          group.joinAll();
          assert(numReaders == 0 && numWriters == 0);
          foreach (t; group) group.remove(t);
      }
      runTest(ReadWriteMutex.Policy.PREFER_READERS);
      runTest(ReadWriteMutex.Policy.PREFER_WRITERS);

  enum Policy: int;
    Defines the policy used by this mutex. Currently, two policies are defined.
    The first will queue writers until no readers hold the mutex, then pass the writers through one at a time. If a reader acquires the mutex while there are still writers queued, the reader will take precedence.

    The second will queue readers if there are any writers queued. Writers are passed through one at a time, and once there are no writers present, all queued readers will be alerted.

    Future policies may offer a more even balance between reader and writer precedence.
    PREFER_READERS
      Readers get preference. This may starve writers.
    PREFER_WRITERS
      Writers get preference. This may starve readers.
  this(Policy policy = Policy.PREFER_WRITERS);
    Initializes a read/write mutex object with the supplied policy.
    Parameters:

    Policy policy | The policy to use.

    Throws:
    SyncError on error.
  @property Policy policy();
    Gets the policy used by this mutex.
    Returns:
    The policy used by this mutex.
  @property Reader reader();
    Gets an object representing the reader lock for the associated mutex.
    Returns:
    A reader sub-mutex.
  @property Writer writer();
    Gets an object representing the writer lock for the associated mutex.
    Returns:
    A writer sub-mutex.
  class Reader: object.Object.Monitor;
    This class can be considered a mutex in its own right, and is used to negotiate a read lock for the enclosing mutex.
    this();
      Initializes a read/write mutex reader proxy object.
    @trusted void lock();
      Acquires a read lock on the enclosing mutex.
    @trusted void unlock();
      Releases a read lock on the enclosing mutex.
    bool tryLock();
      Attempts to acquire a read lock on the enclosing mutex. If one can be obtained without blocking, the lock is acquired and true is returned. If not, the lock is not acquired and false is returned.
      Returns:
      true if the lock was acquired and false if not.
  class Writer: object.Object.Monitor;
    This class can be considered a mutex in its own right, and is used to negotiate a write lock for the enclosing mutex.
    this();
      Initializes a read/write mutex writer proxy object.
    @trusted void lock();
      Acquires a write lock on the enclosing mutex.
    @trusted void unlock();
      Releases a write lock on the enclosing mutex.
    bool tryLock();
      Attempts to acquire a write lock on the enclosing mutex. If one can be obtained without blocking, the lock is acquired and true is returned. If not, the lock is not acquired and false is returned.
      Returns:
      true if the lock was acquired and false if not.

Copyright Sean Kelly 2005 - 2009. | Page generated by Ddoc on Mon Jun 27 20:06:52 2016