D Programming Language 2.0

- Comments
- D
- Search
- Home

Last update Wed Jul 9 01:24:49 2008

# std.typecons

This module implements a variety of type constructors, i.e., templates that allow construction of new, useful general-purpose types.
Synopsis:

    // value tuples
    alias Tuple!(float, "x", float, "y", float, "z") Coord;
    Coord c;
    c._0 = 1;         // access by index-based name
    c.field!(1) = 1;  // access by index
    c.z = 1;          // access by given name
    alias Tuple!(string, string) DicEntry; // names can be omitted

    // enumerated values with conversions to and from strings
    mixin(defineEnum!("Openmode", "READ", "WRITE", "READWRITE", "APPEND"));
    void foo()
    {
        Openmode m = Openmode.READ;
        string s = enumToString(m);
        assert(s == "READ");
        Openmode m1;
        assert(enumFromString(s, m1) && m1 == m);
    }

    // Rebindable references to const and invariant objects
    void bar()
    {
        const w1 = new Widget, w2 = new Widget;
        w1.foo();
        // w1 = w2 would not work; can't rebind const object
        auto r = Rebindable!(const Widget)(w1);
        // invoke method as if r were a Widget object
        r.foo();
        // rebind r to refer to another object
        r = w2;
    }

Author:
Andrei Alexandrescu

struct Tuple(T...);
  Tuple of values, for example Tuple!(int, string) is a record that stores an int and a string. Tuple can be used to bundle values together, notably when returning multiple values from a function. If obj is a tuple, the individual members are accessible with the syntax obj.field!(0) for the first field, obj.field!(1) for the second, and so on. A shortcut notation is obj._0, obj._1 etc.
  The choice of zero-based indexing instead of one-base indexing was motivated by the ability to use value tuples with various compile-time loop constructs (e.g. type tuple iteration), all of which use zero-based indexing.
  Example:

      Tuple!(int, int) point;
      // assign coordinates
      point._0 = 5;
      point.field!(1) = 6;
      // read coordinates
      auto x = point.field!(0);
      auto y = point._1;

  Tuple members can be named. It is legal to mix named and unnamed members. The method above is still applicable to all fields.
  Example:

      alias Tuple!(int, "index", string, "value") Entry;
      Entry e;
      e.index = 4;
      e.value = "Hello";
      assert(e._1 == "Hello");
      assert(e.field!(0) == 4);

  Tuples with named fields are distinct types from tuples with unnamed fields, i.e. each naming imparts a separate type for the tuple. Two tuple differing in naming only are still distinct, even though they might have the same structure.
  Example:

      Tuple!(int, "x", int, "y") point1;
      Tuple!(int, int) point2;
      assert(!is(typeof(point1) == typeof(point2))); // passes

Tuple!(T) tuple(T...)(T args);
  Returns a Tuple object instantiated and initialized according to the arguments.
  Example:

      auto value = tuple(5, 6.7, "hello");
      assert(value._0 == 5);
      assert(value._1 == 6.7);
      assert(value._2 == "hello");

template defineEnum(string name,T...)
  Defines truly named enumerated values with parsing and stringizing primitives.
  Example:

      mixin(defineEnum!("Abc", "A", "B", 5, "C"));

  is equivalent to the following code:

      enum Abc { A, B = 5, C }
      string enumToString(Abc v) { ... }
      Abc enumFromString(string s) { ... }

  The enumToString function generates the unqualified names of the enumerated values, i.e. "A", "B", and "C". The enumFromString function expects one of "A", "B", and "C", and throws an exception in any other case.
  A base type can be specified for the enumeration like this:

      mixin(defineEnum!("Abc", ubyte, "A", "B", "C", 255));

  In this case the generated enum will have a ubyte representation.
template Rebindable(T : Object)
  Rebindable!(T) is a simple, efficient wrapper that behaves just like an object of type T, except that you can reassign it to refer to another object. For completeness, Rebindable!(T) aliases itself away to T if T is a non-const object type. However, Rebindable!(T) does not compile if T is a non-class type.
  Regular const object references cannot be reassigned:

      class Widget { int x; int y() const { return a; } }
      const a = new Widget;
      a.y();          // fine
      a.x = 5;        // error! can't modify const a
      a = new Widget; // error! can't modify const a

  However, Rebindable!(Widget) does allow reassignment, while otherwise behaving exactly like a const Widget:

      auto a = Rebindable!(const Widget)(new Widget);
      a.y();          // fine
      a.x = 5;        // error! can't modify const a
      a = new Widget; // fine

  You may want to use Rebindable when you want to have mutable storage referring to const objects, for example an array of references that must be sorted in place. Rebindable does not break the soundness of D's type system and does not incur any of the risks usually associated with cast.

Copyright © 1999-2008 by Digital Mars, All Rights Reserved | Page generated by Ddoc.